STKBlowBotl

STKBlowBotl — STKBlowBotl utilise un résonateur de Helmholtz (filtre biquadratique) avec une excitation par jet polynomial.

Description

Cet opcode implémente un résonateur de Helmholtz (filtre biquadratique) avec une excitation par jet polynomial (à la Cook).

Syntaxe

asignal STKBlowBotl ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4]]]]

Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

Exécution

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôleurs facultatifs au taux-k pour les opcodes STK. Chaque paire de contrôleurs est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Les 4 numéros de contrôleur et les valeurs qui fonctionnent pour STKBlowBotl sont :

  • kc, kv -- 4, gain du bruit.

  • kc, kv -- 11, vitesse de l'oscillateur basse-fréquence.

  • kc, kv -- 1, intensité de l'oscillateur basse-fréquence.

  • kc, kv -- 128, volume.

[Note] Note

Le code pour cet opcode vient directement de la classe BlowBotl du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html

Exemples

Voici un exemple de l'opcode STKBlowBotl. Il utilise le fichier STKBlowBotl.csd.

Exemple 789. Exemple de l'opcode STKBlowBotl.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o STKBlowBotl.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1

ipch	= p4
knoise	line p5, p3, p6					;noise
kvol	line	100, p3, 70				;volume

asig	STKBlowBotl cpspch(ipch), 1, 4, knoise, 11, 10, 1, 50, 128, kvol
asig	=	asig * .7				;too loud
	outs	asig, asig
endin

</CsInstruments>
<CsScore>

i 1 0 2 9.00 20 100
i 1 + 3 8.03 120 0
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.