STKMoog

STKMoog — STKMoog produit des sons de filtre à balayage comme sur un moog.

Description

STKMoog produit des sons de filtre à balayage comme sur un moog, en utilisant une onde pour l'attaque, une onde pour la boucle et une enveloppe ADSR, et en ajoutant deux filtres à balayage de formant.

Syntaxe

asignal STKMoog ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4[, kc5, kv5]]]]]

Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

Exécution

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôleurs facultatifs au taux-k pour les opcodes STK. Chaque paire de contrôleurs est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Les 5 numéros de contrôleur et les valeurs qui fonctionnent pour STKMoog sont :

  • kc, kv -- 2, Q du filtre.

  • kc, kv -- 4, taux de balayage du filtre.

  • kc, kv -- 11, vitesse de l'oscillateur basse-fréquence.

  • kc, kv -- 1, intensité de l'oscillateur basse-fréquence.

  • kc, kv -- 128, volume.

[Note] Note

Le code pour cet opcode vient directement de la classe Moog du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html

Exemples

Voici un exemple de l'opcode STKMoog. Il utilise le fichier STKMoog.csd.

Exemple 800. Exemple de l'opcode STKMoog.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o STKMoog.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1

ifrq	=	p4
kfil	line	p5, p3, p6				;filter Q

asig	STKMoog cpspch(ifrq), 1, 2,kfil, 4, 120, 11, 40, 1, 1, 128, 120
asig	=	asig * .3				;too loud
	outs asig, asig
endin

</CsInstruments>
<CsScore>

i 1 0 .5 6.00 100 0
i 1 + .  5.05 10 127
i 1 + .  7.06 100 0
i 1 + 3  7.00 10 10
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Michael Gogins (d'après Perry Cook)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.