STKSaxofony

STKSaxofony — STKSaxofony simule un instrument à anche et perce conique.

Description

STKSaxofony simule un instrument à anche et perce conique. Cet opcode utilise un instrument "hybride" à guide d'onde numérique qui peut générer une variété de sons de type vents. Il est aussi connu sous le nom de modèle de "corde soufflée". La section du guide d'onde est essentiellement celle d'une corde, avec une extrémité rigide et l'autre dissipative. La fonction non-linéaire est une table d'anche. La corde peut être "soufflée" n'importe où entre les extrémités, tandis que, comme pour les cordes, il est impossible d'exciter le système à l'une de ses extrémités. Si l'excitation a lieu au milieu de la corde, le son est celui d'une clarinette. Aux points plus proches du "chevalet", le son se rapproche de celui d'un saxophone.

Syntaxe

asignal STKSaxofony ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4[, kc5, kv5[, kc6, kv6[, kc7, kv7]]]]]]]

Initialisation

ifrequency -- Fréquence de la note jouée, en Hz.

iamplitude -- Amplitude de la note jouée (entre 0 et 1).

Exécution

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Jusqu'à 8 paires de contrôleurs facultatifs au taux-k pour les opcodes STK. Chaque paire de contrôleurs est constituée d'un numéro de contrôleur (kc) suivi d'une valeur de contrôleur (kv). Les 7 numéros de contrôleur et les valeurs qui fonctionnent pour STKSaxofony sont :

  • kc, kv -- 2, raideur de l'anche.

  • kc, kv -- 26, ouverture de l'anche.

  • kc, kv -- 11, position su souffle.

  • kc, kv -- 4, gain du bruit.

  • kc, kv -- 29, vitesse de l'oscillateur basse-fréquence.

  • kc, kv -- 1, intensité de l'oscillateur basse-fréquence.

  • kc, kv -- 128, pression du souffle.

[Note] Note

Le code pour cet opcode vient directement de la classe Saxofony du Synthesis Toolkit en C++ par Perry R. Cook et Gary P. Scavone. On peut en savoir plus sur les classes STK ici : https://ccrma.stanford.edu/software/stk/classes.html

Exemples

Voici un exemple de l'opcode STKSaxofony. Il utilise le fichier STKSaxofony.csd.

Exemple 805. Exemple de l'opcode STKSaxofony.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;RT audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o STKSaxofony.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1

ifreq	=	p4
kstiff	=	p5					;reed stiffness
kblw	line	p6, p3, p7				;blow position
kvib	line	0, p3, 127				;vibrato speed

asig	STKSaxofony cpspch(p4), 1, 2, kstiff, 4, 100, 26, 70, 11, kblw, 1, kvib, 29, 100
asig	=	asig * .5				;too loud
	outs asig, asig
endin

</CsInstruments>
<CsScore>

i 1 0 3 6.00 30 100 10
i 1 + . 8.00 30 100 100
i 1 + . 7.00 90 127 30
e
</CsScore>
</CsoundSynthesizer>


Crédits

Auteur : Michael Gogins (d'après Georg Essl)
Irreducible Productions
New York, NY

Nouveau dans la version 5.11 de Csound.