------------------------------------------------------------------------------
--                                                                          --
--                   AI-302 Reference Implementation                        --
--                                                                          --
--              Copyright (C) 2003-2004 Matthew J Heaney                    --
--                                                                          --
-- The AI-302 Reference Implementation ("AI-302") is free software; you can --
-- redistribute it and/or modify it under terms of the GNU General Public   --
-- License as published by the Free Software Foundation; either version 2,  --
-- or (at your option) any later version.  AI-302 is distributed in the     --
-- hope that it will be useful, but WITHOUT ANY WARRANTY; without even the  --
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- See the GNU General Public License for more details.  You should have    --
-- received a copy of the GNU General Public License distributed with       --
-- AI-302;  see file COPYING.TXT.  If not, write to the Free Software       --
-- Foundation,  59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.    --
--                                                                          --
-- As a special exception, if other files instantiate generics from this    --
-- unit, or you link this unit with other files to produce an executable,   --
-- this unit does not by itself cause the resulting executable to be        --
-- covered by the GNU General Public License.  This exception does not      --
-- however invalidate any other reasons why the executable file might be    --
-- covered by the GNU Public License.                                       --
--                                                                          --
-- The AI-302 Reference Implementation is maintained by Matthew J Heaney.   --
--                                                                          --
-- mailto:matthewjheaney@earthlink.net                                      --
-- http://home.earthlink.net/~matthewjheaney/index.html                     --
-- http://charles.tigris.org/                                               --
--                                                                          --
------------------------------------------------------------------------------

package body Ada.Containers.Red_Black_Trees.Generic_Keys is

   package Ops renames Tree_Operations;

   procedure Generic_Insert_Post
     (Tree : in out Tree_Type;
      X, Y : in     Node_Access;
      Key  : in     Key_Type;
      Z    :    out Node_Access) is

      subtype Length_Subtype is Count_Type
        range 0 .. Count_Type'Last - 1;

      New_Length : constant Count_Type :=
        Length_Subtype'(Tree.Length) + 1;

   begin

      if Tree.Busy > 0 then
         raise Program_Error;
      end if;

      if Y = null
        or else X /= null
        or else Is_Less_Key_Node (Key, Y)
      then

         pragma Assert (Y = null
                          or else Ops.Left (Y) = null);

         --  Delay allocation as long as we can, in order to defend
         --  against exceptions propagated by relational operators.

         Z := New_Node;

         pragma Assert (Z /= null);
         pragma Assert (Ops.Color (Z) = Red);

         if Y = null then

            pragma Assert (Tree.Length = 0);
            pragma Assert (Tree.Root = null);
            pragma Assert (Tree.First = null);
            pragma Assert (Tree.Last = null);

            Tree.Root := Z;
            Tree.First := Z;
            Tree.Last := Z;

         else

            Ops.Set_Left (Y, Z);

            if Y = Tree.First then
               Tree.First := Z;
            end if;

         end if;

      else

         pragma Assert (Ops.Right (Y) = null);

         --  Delay allocation as long as we can, in order to defend
         --  against exceptions propagated by relational operators.

         Z := New_Node;

         pragma Assert (Z /= null);
         pragma Assert (Ops.Color (Z) = Red);

         Ops.Set_Right (Y, Z);

         if Y = Tree.Last then
            Tree.Last := Z;
         end if;

      end if;

      Ops.Set_Parent (Z, Y);

      Ops.Rebalance_For_Insert (Tree, Z);

      Tree.Length := New_Length;

   end Generic_Insert_Post;



   procedure Generic_Conditional_Insert
     (Tree     : in out Tree_Type;
      Key      : in     Key_Type;
      Node     :    out Node_Access;
      Inserted :    out Boolean) is

      Y : Node_Access := null;
      X : Node_Access := Tree.Root;

   begin

      Inserted := True;

      while X /= null loop

         Y := X;

         Inserted := Is_Less_Key_Node (Key, X);

         if Inserted then
            X := Ops.Left (X);
         else
            X := Ops.Right (X);
         end if;

      end loop;

      Node := Y;

      if Inserted then

         if Node = Tree.First then
            Insert_Post (Tree, X, Y, Key, Node);
            return;
         end if;

         Node := Ops.Previous (Node);

      end if;

      if Is_Greater_Key_Node (Key, Node) then
         Insert_Post (Tree, X, Y, Key, Node);
         Inserted := True;
         return;
      end if;

      Inserted := False;

   end Generic_Conditional_Insert;


   procedure Generic_Unconditional_Insert
     (Tree : in out Tree_Type;
      Key  : in     Key_Type;
      Node :    out Node_Access) is

      Y : Node_Access := null;
      X : Node_Access := Tree.Root;

   begin

      while X /= null loop

         Y := X;

         if Is_Less_Key_Node (Key, X) then
            X := Ops.Left (X);
         else
            X := Ops.Right (X);
         end if;

      end loop;

      Insert_Post (Tree, X, Y, Key, Node);

   end Generic_Unconditional_Insert;



   procedure Generic_Unconditional_Insert_With_Hint
     (Tree : in out Tree_Type;
      Hint : in     Node_Access;
      Key  : in     Key_Type;
      Node :    out Node_Access) is

      --  TODO: verify this algorithm.  I (quickly) adapted it from the
      --  same algorithm for conditional_with_hint.  I think that the
      --  test Key > Hint should be something like a Key >= Hint, to
      --  handle the case when Hint is the last item of a (contiguous)
      --  sequence of equivalent items.  (The Key < Hint test is
      --  probably OK.  I don't think you can use Key <= Hint, since
      --  new items are always inserted last in the sequence of
      --  equivalent items.)

   begin

      if Hint = null then  -- largest

         if Tree.Length > 0
           and then Is_Greater_Key_Node (Key, Tree.Last)
         then
            Insert_Post (Tree, null, Tree.Last, Key, Node);
         else
            Unconditional_Insert_Sans_Hint (Tree, Key, Node);
         end if;

         return;

      end if;

      pragma Assert (Tree.Length > 0);

      if Is_Less_Key_Node (Key, Hint) then

         if Hint = Tree.First then
            Insert_Post (Tree, Hint, Hint, Key, Node);
            return;
         end if;

         declare
            Before : constant Node_Access := Ops.Previous (Hint);
         begin
            if Is_Greater_Key_Node (Key, Before) then

               if Ops.Right (Before) = null then
                  Insert_Post (Tree, null, Before, Key, Node);
               else
                  Insert_Post (Tree, Hint, Hint, Key, Node);
               end if;

            else
               Unconditional_Insert_Sans_Hint (Tree, Key, Node);
            end if;
         end;

         return;

      end if;

      if Is_Greater_Key_Node (Key, Hint) then

         if Hint = Tree.Last then
            Insert_Post (Tree, null, Tree.Last, Key, Node);
            return;
         end if;

         declare
            After : constant Node_Access := Ops.Next (Hint);
         begin
            if Is_Less_Key_Node (Key, After) then

               if Ops.Right (Hint) = null then
                  Insert_Post (Tree, null, Hint, Key, Node);
               else
                  Insert_Post (Tree, After, After, Key, Node);
               end if;

            else
               Unconditional_Insert_Sans_Hint (Tree, Key, Node);
            end if;
         end;

         return;

      end if;

      Unconditional_Insert_Sans_Hint (Tree, Key, Node);

   end Generic_Unconditional_Insert_With_Hint;


   procedure Generic_Conditional_Insert_With_Hint
     (Tree     : in out Tree_Type;
      Position : in     Node_Access;
      Key      : in     Key_Type;
      Node     :    out Node_Access;
      Inserted :    out Boolean) is

   begin

      if Position = null then  -- largest

         if Tree.Length > 0
           and then Is_Greater_Key_Node (Key, Tree.Last)
         then
            Insert_Post (Tree, null, Tree.Last, Key, Node);
            Inserted := True;
         else
            Conditional_Insert_Sans_Hint (Tree, Key, Node, Inserted);
         end if;

         return;

      end if;

      pragma Assert (Tree.Length > 0);

      if Is_Less_Key_Node (Key, Position) then

         if Position = Tree.First then
            Insert_Post (Tree, Position, Position, Key, Node);
            Inserted := True;
            return;
         end if;

         declare
            Before : constant Node_Access := Ops.Previous (Position);
         begin
            if Is_Greater_Key_Node (Key, Before) then

               if Ops.Right (Before) = null then
                  Insert_Post (Tree, null, Before, Key, Node);
               else
                  Insert_Post (Tree, Position, Position, Key, Node);
               end if;

               Inserted := True;

            else
               Conditional_Insert_Sans_Hint (Tree, Key, Node, Inserted);
            end if;
         end;

         return;

      end if;

      if Is_Greater_Key_Node (Key, Position) then

         if Position = Tree.Last then
            Insert_Post (Tree, null, Tree.Last, Key, Node);
            Inserted := True;
            return;
         end if;

         declare
            After : constant Node_Access := Ops.Next (Position);
         begin
            if Is_Less_Key_Node (Key, After) then

               if Ops.Right (Position) = null then
                  Insert_Post (Tree, null, Position, Key, Node);
               else
                  Insert_Post (Tree, After, After, Key, Node);
               end if;

               Inserted := True;

            else
               Conditional_Insert_Sans_Hint (Tree, Key, Node, Inserted);
            end if;
         end;

         return;

      end if;

      Node := Position;
      Inserted := False;

   end Generic_Conditional_Insert_With_Hint;


   function Find
     (Tree : Tree_Type;
      Key  : Key_Type) return Node_Access is

      Y : Node_Access;
      X : Node_Access := Tree.Root;

   begin

      while X /= null loop

         if Is_Greater_Key_Node (Key, X) then
            X := Ops.Right (X);
         else
            Y := X;
            X := Ops.Left (X);
         end if;

      end loop;

      if Y = null then
         return null;
      end if;

      if Is_Less_Key_Node (Key, Y) then
         return null;
      end if;

      return Y;

   end Find;


   function Ceiling  --  AKA Lower_Bound
     (Tree : Tree_Type;
      Key  : Key_Type) return Node_Access is

      Y : Node_Access;
      X : Node_Access := Tree.Root;

   begin

      while X /= null loop

         if Is_Greater_Key_Node (Key, X) then
            X := Ops.Right (X);
         else
            Y := X;
            X := Ops.Left (X);
         end if;

      end loop;

      return Y;

   end Ceiling;


   function Floor
     (Tree : Tree_Type;
      Key  : Key_Type) return Node_Access is

      Y : Node_Access;
      X : Node_Access := Tree.Root;

   begin

      while X /= null loop

         if Is_Less_Key_Node (Key, X) then
            X := Ops.Left (X);
         else
            Y := X;
            X := Ops.Right (X);
         end if;

      end loop;

      return Y;

   end Floor;


   function Upper_Bound
     (Tree : Tree_Type;
      Key  : Key_Type) return Node_Access is

      Y : Node_Access;
      X : Node_Access := Tree.Root;

   begin

      while X /= null loop

         if Is_Less_Key_Node (Key, X) then
            Y := X;
            X := Ops.Left (X);
         else
            X := Ops.Right (X);
         end if;

      end loop;

      return Y;

   end Upper_Bound;


   procedure Generic_Iteration
     (Tree : Tree_Type;
      Key  : Key_Type) is

      procedure Iterate (Node : Node_Access);

      procedure Iterate (Node : Node_Access) is
         N : Node_Access := Node;
      begin

         while N /= null loop

            if Is_Less_Key_Node (Key, N) then
               N := Ops.Left (N);

            elsif Is_Greater_Key_Node (Key, N) then
               N := Ops.Right (N);

            else
               Iterate (Ops.Left (N));
               Process (N);
               N := Ops.Right (N);

            end if;

         end loop;

      end Iterate;

   begin

      Iterate (Tree.Root);

   end Generic_Iteration;


   procedure Generic_Reverse_Iteration
     (Tree : Tree_Type;
      Key  : Key_Type) is

      procedure Iterate (Node : Node_Access);

      procedure Iterate (Node : Node_Access) is
         N : Node_Access := Node;
      begin

         while N /= null loop

            if Is_Less_Key_Node (Key, N) then
               N := Ops.Left (N);

            elsif Is_Greater_Key_Node (Key, N) then
               N := Ops.Right (N);

            else
               Iterate (Ops.Right (N));
               Process (N);
               N := Ops.Left (N);

            end if;

         end loop;

      end Iterate;

   begin

      Iterate (Tree.Root);

   end Generic_Reverse_Iteration;


end Ada.Containers.Red_Black_Trees.Generic_Keys;



