------------------------------------------------------------------------------
--                                                                          --
--                   AI-302 Reference Implementation                        --
--                                                                          --
--              Copyright (C) 2003-2004 Matthew J Heaney                    --
--                                                                          --
-- The AI-302 Reference Implementation ("AI-302") is free software; you can --
-- redistribute it and/or modify it under terms of the GNU General Public   --
-- License as published by the Free Software Foundation; either version 2,  --
-- or (at your option) any later version.  AI-302 is distributed in the     --
-- hope that it will be useful, but WITHOUT ANY WARRANTY; without even the  --
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- See the GNU General Public License for more details.  You should have    --
-- received a copy of the GNU General Public License distributed with       --
-- AI-302;  see file COPYING.TXT.  If not, write to the Free Software       --
-- Foundation,  59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.    --
--                                                                          --
-- As a special exception, if other files instantiate generics from this    --
-- unit, or you link this unit with other files to produce an executable,   --
-- this unit does not by itself cause the resulting executable to be        --
-- covered by the GNU General Public License.  This exception does not      --
-- however invalidate any other reasons why the executable file might be    --
-- covered by the GNU Public License.                                       --
--                                                                          --
-- The AI-302 Reference Implementation is maintained by Matthew J Heaney.   --
--                                                                          --
-- mailto:matthewjheaney@earthlink.net                                      --
-- http://home.earthlink.net/~matthewjheaney/index.html                     --
-- http://charles.tigris.org/                                               --
--                                                                          --
------------------------------------------------------------------------------

with Ada.Unchecked_Deallocation; -- needs pragma too?

with Ada.Containers.Red_Black_Trees.Generic_Operations;
pragma Elaborate_All (Ada.Containers.Red_Black_Trees.Generic_Operations);

with Ada.Containers.Red_Black_Trees.Generic_Keys;
pragma Elaborate_All (Ada.Containers.Red_Black_Trees.Generic_Keys);

with System.Address_To_Access_Conversions;
pragma Elaborate_All (System.Address_To_Access_Conversions);

package body Ada.Containers.Indefinite_Ordered_Maps is

   function Parent (Node : Node_Access) return Node_Access;
   pragma Inline (Parent);

   function Parent (Node : Node_Access)
      return Node_Access is
   begin
      return Node.Parent;
   end Parent;

   function Left (Node : Node_Access) return Node_Access;
   pragma Inline (Left);

   function Left (Node : Node_Access)
      return Node_Access is
   begin
      return Node.Left;
   end Left;

   function Right (Node : Node_Access) return Node_Access;
   pragma Inline (Right);

   function Right (Node : Node_Access)
      return Node_Access is
   begin
      return Node.Right;
   end Right;

   function Color (Node : Node_Access) return Color_Type;
   pragma Inline (Color);

   function Color (Node : Node_Access)
      return Color_Type is
   begin
      return Node.Color;
   end Color;

   procedure Set_Parent
     (Node   : Node_Access;
      Parent : Node_Access);
   pragma Inline (Set_Parent);

   procedure Set_Parent
     (Node   : Node_Access;
      Parent : Node_Access) is
   begin
      Node.Parent := Parent;
   end Set_Parent;

   procedure Set_Left
     (Node : Node_Access;
      Left : Node_Access);
   pragma Inline (Set_Left);

   procedure Set_Left
     (Node : Node_Access;
      Left : Node_Access) is
   begin
      Node.Left := Left;
   end Set_Left;

   procedure Set_Right
     (Node  : Node_Access;
      Right : Node_Access);
   pragma Inline (Set_Right);

   procedure Set_Right
     (Node  : Node_Access;
      Right : Node_Access) is
   begin
      Node.Right := Right;
   end Set_Right;

   procedure Set_Color
     (Node  : Node_Access;
      Color : Color_Type);
   pragma Inline (Set_Color);

   procedure Set_Color
     (Node  : Node_Access;
      Color : Color_Type) is
   begin
      Node.Color := Color;
   end Set_Color;


   package Tree_Ops is
      new Red_Black_Trees.Generic_Operations (Tree_Types);

   use Tree_Ops;


   function Is_Greater_Key_Node
     (Left  : Key_Type;
      Right : Node_Access) return Boolean;
   pragma Inline (Is_Greater_Key_Node);

   function Is_Greater_Key_Node
     (Left  : Key_Type;
      Right : Node_Access) return Boolean is

      --  k > node same as node < k
   begin
      return Right.Key.all < Left;
   end Is_Greater_Key_Node;


   function Is_Less_Key_Node
     (Left  : Key_Type;
      Right : Node_Access) return Boolean;
   pragma Inline (Is_Less_Key_Node);

   function Is_Less_Key_Node
     (Left  : Key_Type;
      Right : Node_Access) return Boolean is
   begin
      return Left < Right.Key.all;
   end Is_Less_Key_Node;


   package Key_Ops is
      new Red_Black_Trees.Generic_Keys
       (Tree_Operations     => Tree_Ops,
        Key_Type            => Key_Type,
        Is_Less_Key_Node    => Is_Less_Key_Node,
        Is_Greater_Key_Node => Is_Greater_Key_Node);


   package Pointer_Types is
      new System.Address_To_Access_Conversions (Map);

   use Pointer_Types;


   procedure Free_Key is
      new Ada.Unchecked_Deallocation (Key_Type, Key_Access);

   procedure Free_Element is
      new Ada.Unchecked_Deallocation (Element_Type, Element_Access);

   procedure Free (X : in out Node_Access);

   procedure Free (X : in out Node_Access) is

      procedure Deallocate is
        new Ada.Unchecked_Deallocation (Node_Type, Node_Access);

   begin

      if X = null then
         return;
      end if;

      begin
         Free_Key (X.Key);
      exception
         when others =>
            X.Key := null;

            begin
               Free_Element (X.Element);
            exception
               when others =>
                  X.Element := null;
            end;

            Deallocate (X);
            raise;
      end;

      begin
         Free_Element (X.Element);
      exception
         when others =>
            X.Element := null;
            Deallocate (X);
            raise;
      end;

      Deallocate (X);

   end Free;

   procedure Delete_Tree is
      new Tree_Ops.Generic_Delete_Tree (Free);

   procedure Clear is
      new Tree_Ops.Generic_Clear (Delete_Tree);


   function Copy_Node (Source : Node_Access) return Node_Access;
   pragma Inline (Copy_Node);

   function Copy_Node (Source : Node_Access) return Node_Access is
      K : Key_Access := new Key_Type'(Source.Key.all);
      E : Element_Access;
   begin
      E := new Element_Type'(Source.Element.all);

      return new Node_Type'(Parent  => null,
                            Left    => null,
                            Right   => null,
                            Color   => Source.Color,
                            Key     => K,
                            Element => E);
   exception
      when others =>
         Free_Key (K);
         Free_Element (E);
         raise;
   end Copy_Node;

   function Copy_Tree is
      new Tree_Ops.Generic_Copy_Tree (Copy_Node, Delete_Tree);

   procedure Adjust is
      new Tree_Ops.Generic_Adjust (Copy_Tree);

   procedure Adjust (Container : in out Map) is
   begin
      Adjust (Container.Tree);
   end Adjust;


   procedure Write_Node
     (Stream : access Root_Stream_Type'Class;
      Node   : in     Node_Access);
   pragma Inline (Write_Node);

   procedure Write_Node
     (Stream : access Root_Stream_Type'Class;
      Node   : in     Node_Access) is
   begin
      Key_Type'Output (Stream, Node.Key.all);
      Element_Type'Output (Stream, Node.Element.all);
   end Write_Node;

   procedure Write is
      new Tree_Ops.Generic_Write (Write_Node);

   procedure Write
     (Stream    : access Root_Stream_Type'Class;
      Container : in     Map) is
   begin
      Write (Stream, Container.Tree);
   end Write;


   function Read_Node
     (Stream : access Root_Stream_Type'Class) return Node_Access;
   pragma Inline (Read_Node);

   function Read_Node
     (Stream : access Root_Stream_Type'Class) return Node_Access is

      Node : Node_Access := new Node_Type;
   begin
      Node.Key := new Key_Type'(Key_Type'Input (Stream));
      Node.Element := new Element_Type'(Element_Type'Input (Stream));
      return Node;
   exception
      when others =>
         Free (Node);  --  free's key and elem too
         raise;
   end Read_Node;

   procedure Read is
      new Tree_Ops.Generic_Read (Clear, Read_Node);

   procedure Read
     (Stream    : access Root_Stream_Type'Class;
      Container :    out Map) is
   begin
      Read (Stream, Container.Tree);
   end Read;


   function Is_Equal_Node_Node
     (L, R : Node_Access) return Boolean;
   pragma Inline (Is_Equal_Node_Node);

   function Is_Equal_Node_Node
     (L, R : Node_Access) return Boolean is
   begin
      if L.Key.all < R.Key.all then
         return False;

      elsif R.Key.all < L.Key.all then
         return False;

      else
         return L.Element.all = R.Element.all;

      end if;
   end Is_Equal_Node_Node;

   function Is_Equal is
      new Tree_Ops.Generic_Equal (Is_Equal_Node_Node);

   function "=" (Left, Right : Map) return Boolean is
   begin
      return Is_Equal (Left.Tree, Right.Tree);
   end "=";


   function Length (Container : Map) return Count_Type is
   begin
      return Container.Tree.Length;
   end Length;


   function Is_Empty (Container : Map) return Boolean is
   begin
      return Container.Tree.Length = 0;
   end Is_Empty;


   procedure Clear (Container : in out Map) is
   begin
      Clear (Container.Tree);
   end Clear;


   function Key (Position : Cursor) return Key_Type is
   begin
      return Position.Node.Key.all;
   end Key;


   function Element (Position : Cursor) return Element_Type is
   begin
      return Position.Node.Element.all;
   end Element;


   procedure Query_Element
     (Position : in Cursor;
      Process  : not null access procedure (Key     : in Key_Type;
                                            Element : in Element_Type)) is

      --  TODO: pragma Assert (Vet (Position));

      K : Key_Type renames Position.Node.Key.all;
      E : Element_Type renames Position.Node.Element.all;

      C : Map renames To_Pointer (Position.Container.all'Address).all;
      B : Natural renames C.Tree.Busy;
      L : Natural renames C.Tree.Lock;

   begin

      B := B + 1;
      L := L + 1;

      begin
         Process (K, E);
      exception
         when others =>
            L := L - 1;
            B := B - 1;
            raise;
      end;

      L := L - 1;
      B := B - 1;

   end Query_Element;


   procedure Update_Element
     (Position : in Cursor;
      Process  : not null access procedure (Key     : in     Key_Type;
                                            Element : in out Element_Type)) is

      --  TODO: pragma Assert (Vet (Position));

      K : Key_Type renames Position.Node.Key.all;
      E : Element_Type renames Position.Node.Element.all;

      C : Map renames To_Pointer (Position.Container.all'Address).all;
      B : Natural renames C.Tree.Busy;
      L : Natural renames C.Tree.Lock;

   begin

      B := B + 1;
      L := L + 1;

      begin
         Process (K, E);
      exception
         when others =>
            L := L - 1;
            B := B - 1;
            raise;
      end;

      L := L - 1;
      B := B - 1;

   end Update_Element;


   procedure Replace_Element (Position : in Cursor;
                              By       : in Element_Type) is

      X : Element_Access := Position.Node.Element;

   begin

      if Position.Container.Tree.Lock > 0 then
         raise Program_Error;
      end if;

      Position.Node.Element := new Element_Type'(By);

      Free_Element (X);

   end Replace_Element;


   procedure Move is
      new Tree_Ops.Generic_Move (Clear);

   procedure Move (Target : in out Map;
                   Source : in out Map) is
   begin
      Move (Target => Target.Tree, Source => Source.Tree);
   end Move;


   procedure Insert (Container : in out Map;
                     Key       : in     Key_Type;
                     New_Item  : in     Element_Type;
                     Position  :    out Cursor;
                     Inserted  :    out Boolean) is

      function New_Node return Node_Access;
      pragma Inline (New_Node);

      function New_Node return Node_Access is
         Node : Node_Access := new Node_Type;
      begin
         Node.Key := new Key_Type'(Key);
         Node.Element := new Element_Type'(New_Item);
         return Node;
      exception
         when others =>
            Free (Node);  --  deallocates key and elem, too
            raise;
      end New_Node;

      procedure Insert_Post is
         new Key_Ops.Generic_Insert_Post (New_Node);

      procedure Insert_Sans_Hint is
         new Key_Ops.Generic_Conditional_Insert (Insert_Post);

   begin -- Insert

      Insert_Sans_Hint
        (Container.Tree,
         Key,
         Position.Node,
         Inserted);

      Position.Container := Container'Unchecked_Access;

      --  pragma Debug (Check_Invariant (Container.Tree));

   end Insert;


   procedure Insert (Container : in out Map;
                     Key       : in     Key_Type;
                     New_Item  : in     Element_Type) is

      Position : Cursor;
      Inserted : Boolean;

   begin

      Insert (Container, Key, New_Item, Position, Inserted);

      if not Inserted then
         raise Constraint_Error;
      end if;

   end Insert;



   procedure Include (Container : in out Map;
                      Key       : in     Key_Type;
                      New_Item  : in     Element_Type) is

      Position : Cursor;
      Inserted : Boolean;

      K : Key_Access;
      E : Element_Access;

   begin

      Insert (Container, Key, New_Item, Position, Inserted);

      if not Inserted then

         if Container.Tree.Lock > 0 then
            raise Program_Error;
         end if;

         K := Position.Node.Key;
         E := Position.Node.Element;

         Position.Node.Key := new Key_Type'(Key);

         begin
            Position.Node.Element := new Element_Type'(New_Item);
         exception
            when others =>
               Free_Key (K);
               raise;
         end;

         Free_Key (K);
         Free_Element (E);

      end if;

   end Include;


   procedure Replace (Container : in out Map;
                      Key       : in     Key_Type;
                      New_Item  : in     Element_Type) is

      Node : constant Node_Access :=
        Key_Ops.Find (Container.Tree, Key);

      K : Key_Access;
      E : Element_Access;

   begin

      if Node = null then
         raise Constraint_Error;
      end if;

      if Container.Tree.Lock > 0 then
         raise Program_Error;
      end if;

      K := Node.Key;
      E := Node.Element;

      Node.Key := new Key_Type'(Key);

      begin
         Node.Element := new Element_Type'(New_Item);
      exception
         when others =>
            Free_Key (K);
            raise;
      end;

      Free_Key (K);
      Free_Element (E);

   end Replace;


   procedure Delete (Container : in out Map;
                     Position  : in out Cursor) is

   begin

      if Position.Node = null then
         raise Constraint_Error;
      end if;

      if Position.Container /= Map_Access'(Container'Unchecked_Access) then
         raise Program_Error;
      end if;

      Tree_Ops.Delete_Node_Sans_Free (Container.Tree, Position.Node);

      Free (Position.Node);
      Position.Container := null;

   end Delete;


   procedure Delete (Container : in out Map;
                     Key       : in     Key_Type) is

      X : Node_Access := Key_Ops.Find (Container.Tree, Key);

   begin

      if X = null then
         raise Constraint_Error;
      end if;

      Tree_Ops.Delete_Node_Sans_Free (Container.Tree, X);

      Free (X);

   end Delete;


   procedure Exclude (Container : in out Map;
                      Key       : in     Key_Type) is

      X : Node_Access := Key_Ops.Find (Container.Tree, Key);
   begin
      if X /= null then
         Delete_Node_Sans_Free (Container.Tree, X);
         Free (X);
      end if;
   end Exclude;


   procedure Delete_First (Container : in out Map) is
      X : Node_Access := Container.Tree.First;
   begin
      if X /= null then
         Tree_Ops.Delete_Node_Sans_Free (Container.Tree, X);
         Free (X);
      end if;
   end Delete_First;


   procedure Delete_Last (Container : in out Map) is
      X : Node_Access := Container.Tree.Last;
   begin
      if X /= null then
         Tree_Ops.Delete_Node_Sans_Free (Container.Tree, X);
         Free (X);
      end if;
   end Delete_Last;


   function Floor (Container : Map;
                   Key       : Key_Type) return Cursor is

      Node : constant Node_Access :=
        Key_Ops.Floor (Container.Tree, Key);
   begin
      if Node = null then
         return No_Element;
      end if;

      return Cursor'(Container'Unchecked_Access, Node);
   end Floor;


   function Ceiling (Container : Map;
                     Key       : Key_Type) return Cursor is

      Node : constant Node_Access :=
        Key_Ops.Ceiling (Container.Tree, Key);
   begin
      if Node = null then
         return No_Element;
      end if;

      return Cursor'(Container'Unchecked_Access, Node);
   end Ceiling;


   function Find (Container : Map;
                  Key       : Key_Type) return Cursor is

      Node : constant Node_Access :=
        Key_Ops.Find (Container.Tree, Key);
   begin
      if Node = null then
         return No_Element;
      end if;

      return Cursor'(Container'Unchecked_Access, Node);
   end Find;


   function Contains (Container : Map;
                      Key       : Key_Type) return Boolean is
   begin
      return Find (Container, Key) /= No_Element;
   end Contains;


   function Element (Container : Map;
                     Key       : Key_Type) return Element_Type is

      Node : constant Node_Access :=
        Key_Ops.Find (Container.Tree, Key);
   begin
      return Node.Element.all;
   end Element;


   function First (Container : Map) return Cursor is
   begin
      if Container.Tree.First = null then
         return No_Element;
      end if;

      return Cursor'(Container'Unchecked_Access, Container.Tree.First);
   end First;


   function First_Key (Container : Map) return Key_Type is
   begin
      return Container.Tree.First.Key.all;
   end First_Key;


   function First_Element (Container : Map) return Element_Type is
   begin
      return Container.Tree.First.Element.all;
   end First_Element;


   function Last (Container : Map) return Cursor is
   begin
      if Container.Tree.Last = null then
         return No_Element;
      end if;

      return Cursor'(Container'Unchecked_Access, Container.Tree.Last);
   end Last;


   function Last_Key (Container : Map) return Key_Type is
   begin
      return Container.Tree.Last.Key.all;
   end Last_Key;


   function Last_Element (Container : Map) return Element_Type is
   begin
      return Container.Tree.Last.Element.all;
   end Last_Element;


   function Next (Position : Cursor) return Cursor is
   begin
      if Position = No_Element then
         return No_Element;
      end if;

      declare
         Node : constant Node_Access :=
           Tree_Ops.Next (Position.Node);
      begin
         if Node = null then
            return No_Element;
         end if;

         return Cursor'(Position.Container, Node);
      end;
   end Next;


   function Previous (Position : Cursor) return Cursor is
   begin
      if Position = No_Element then
         return No_Element;
      end if;

      declare
         Node : constant Node_Access :=
           Tree_Ops.Previous (Position.Node);
      begin
         if Node = null then
            return No_Element;
         end if;

         return Cursor'(Position.Container, Node);
      end;
   end Previous;


   procedure Next (Position : in out Cursor) is
   begin
      Position := Next (Position);
   end Next;


   procedure Previous (Position : in out Cursor) is
   begin
      Position := Previous (Position);
   end Previous;


   function Has_Element (Position : Cursor) return Boolean is
   begin
      return Position /= No_Element;
   end Has_Element;


   function "<" (Left, Right : Cursor) return Boolean is
   begin
      return Left.Node.Key.all < Right.Node.Key.all;
   end "<";


   function ">" (Left, Right : Cursor) return Boolean is
   begin
      return Right.Node.Key.all < Left.Node.Key.all;
   end ">";


   function "<" (Left : Cursor; Right : Key_Type) return Boolean is
   begin
      return Left.Node.Key.all < Right;
   end "<";


   function ">" (Left : Cursor; Right : Key_Type) return Boolean is
   begin
      return Right < Left.Node.Key.all;
   end ">";


   function "<" (Left : Key_Type; Right : Cursor) return Boolean is
   begin
      return Left < Right.Node.Key.all;
   end "<";


   function ">" (Left : Key_Type; Right : Cursor) return Boolean is
   begin
      return Right.Node.Key.all < Left;
   end ">";


   procedure Iterate
     (Container : in Map;
      Process   : not null access procedure (Position : in Cursor)) is

      procedure Process_Node (Node : Node_Access);
      pragma Inline (Process_Node);

      procedure Process_Node (Node : Node_Access) is
      begin
         Process (Cursor'(Container'Unchecked_Access, Node));
      end Process_Node;

      procedure Iterate is
         new Tree_Ops.Generic_Iteration (Process_Node);

      C : Map renames To_Pointer (Container'Address).all;
      B : Natural renames C.Tree.Busy;

   begin

      B := B + 1;

      begin
         Iterate (Container.Tree);
      exception
         when others =>
            B := B - 1;
            raise;
      end;

      B := B - 1;

   end Iterate;


   procedure Reverse_Iterate
     (Container : in Map;
      Process   : not null access procedure (Position : in Cursor)) is

      procedure Process_Node (Node : Node_Access);
      pragma Inline (Process_Node);

      procedure Process_Node (Node : Node_Access) is
      begin
         Process (Cursor'(Container'Unchecked_Access, Node));
      end Process_Node;

      procedure Reverse_Iterate is
         new Tree_Ops.Generic_Reverse_Iteration (Process_Node);

      C : Map renames To_Pointer (Container'Address).all;
      B : Natural renames C.Tree.Busy;

   begin

      B := B + 1;

      begin
         Reverse_Iterate (Container.Tree);
      exception
         when others =>
            B := B - 1;
            raise;
      end;

      B := B - 1;

   end Reverse_Iterate;


end Ada.Containers.Indefinite_Ordered_Maps;


