------------------------------------------------------------------------------
--                                                                          --
--                   AI-302 Reference Implementation                        --
--                                                                          --
--              Copyright (C) 2003-2004 Matthew J Heaney                    --
--                                                                          --
-- The AI-302 Reference Implementation ("AI-302") is free software; you can --
-- redistribute it and/or modify it under terms of the GNU General Public   --
-- License as published by the Free Software Foundation; either version 2,  --
-- or (at your option) any later version.  AI-302 is distributed in the     --
-- hope that it will be useful, but WITHOUT ANY WARRANTY; without even the  --
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- See the GNU General Public License for more details.  You should have    --
-- received a copy of the GNU General Public License distributed with       --
-- AI-302;  see file COPYING.TXT.  If not, write to the Free Software       --
-- Foundation,  59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.    --
--                                                                          --
-- As a special exception, if other files instantiate generics from this    --
-- unit, or you link this unit with other files to produce an executable,   --
-- this unit does not by itself cause the resulting executable to be        --
-- covered by the GNU General Public License.  This exception does not      --
-- however invalidate any other reasons why the executable file might be    --
-- covered by the GNU Public License.                                       --
--                                                                          --
-- The AI-302 Reference Implementation is maintained by Matthew J Heaney.   --
--                                                                          --
-- mailto:matthewjheaney@earthlink.net                                      --
-- http://home.earthlink.net/~matthewjheaney/index.html                     --
-- http://charles.tigris.org/                                               --
--                                                                          --
------------------------------------------------------------------------------

package body Ada.Containers.Hash_Tables.Generic_Keys is

   function Index
     (HT  : Hash_Table_Type;
      Key : Key_Type) return Hash_Type is
   begin
      return Hash (Key) mod HT.Buckets'Length;
   end Index;


   procedure Generic_Conditional_Insert
     (HT       : in out Hash_Table_Type;
      Key      : in     Key_Type;
      Node     :    out Node_Access;
      Inserted :    out Boolean) is

      I : constant Hash_Type := Index (HT, Key);

      B : Node_Access renames HT.Buckets (I);

      subtype Length_Subtype is Count_Type
        range 0 .. Count_Type'Last - 1;

   begin

      if B = null then

         if HT.Busy > 0 then
            raise Program_Error;
         end if;

         declare
            Length : constant Length_Subtype := HT.Length;
         begin
            Node := New_Node (Next => null);
            Inserted := True;

            B := Node;
            HT.Length := Length + 1;
         end;

         return;

      end if;

      Node := B;

      loop

         if Equivalent_Keys (Key, Node) then
            Inserted := False;
            return;
         end if;

         Node := Next (Node);

         exit when Node = null;

      end loop;

      if HT.Busy > 0 then
         raise Program_Error;
      end if;

      declare
         Length : constant Length_Subtype := HT.Length;
      begin
         Node := New_Node (Next => B);
         Inserted := True;

         B := Node;
         HT.Length := Length + 1;
      end;

   end Generic_Conditional_Insert;


   procedure Delete_Key_Sans_Free
     (HT   : in out Hash_Table_Type;
      Key  : in     Key_Type;
      X    :    out Node_Access) is

      I    : Hash_Type;
      Prev : Node_Access;

   begin

      if HT.Length = 0 then
         X := null;
         return;
      end if;

      I := Index (HT, Key);
      X := HT.Buckets (I);

      if X = null then
         return;
      end if;

      if Equivalent_Keys (Key, X) then

         if HT.Busy > 0 then
            raise Program_Error;
         end if;

         HT.Buckets (I) := Next (X);
         HT.Length := HT.Length - 1;

         return;

      end if;

      loop

         Prev := X;
         X := Next (Prev);

         if X = null then
            return;
         end if;

         if Equivalent_Keys (Key, X) then

            if HT.Busy > 0 then
               raise Program_Error;
            end if;

            Set_Next (Node => Prev, Next => Next (X));
            HT.Length := HT.Length - 1;

            return;

         end if;

      end loop;

   end Delete_Key_Sans_Free;



   function Find
     (HT  : Hash_Table_Type;
      Key : Key_Type) return Node_Access is

      I : Hash_Type;
      Node : Node_Access;

   begin

      if HT.Length = 0 then
         return null;
      end if;

      I := Index (HT, Key);
      Node := HT.Buckets (I);

      while Node /= null loop

         if Equivalent_Keys (Key, Node) then
            return Node;
         end if;

         Node := Next (Node);

      end loop;

      return null;

   end Find;



end Ada.Containers.Hash_Tables.Generic_Keys;
