Помощ за LibreOffice 7.3
Този раздел съдържа описания на функциите за текст.
To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.
The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).
To place a literal double quotation mark within a string inside a formula, two methods can be used:
You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.
You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.
Beware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the toggle button to disable the feature.
Преобразува число в тайски текст, включително имената на тайските парични единици.
BAHTTEXT(Число)
Число е произволно число. Към цялата му част се добавя „бат“, а към дробната – „сатанг“.
=BAHTTEXT(12,65) връща низ от тайски знаци със значение „Дванайсет бата и шейсет и пет сатанга“.
Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.
BASE(Число; Основа [; МинималнаДължина])
Число е положително число, което ще се преобразува.
Основа указва основата на бройната система – положително цяло число между 2 и 36.
МинималнаДължина (незадължителен) определя минималната дължина на създаваната поредица от знаци. Ако текстът е по-къс от зададената минимална дължина, низът се допълва отляво с нули.
=BASE(17;10;4) връща 0017 в десетичната система.
=BASE(17;2) връща 10001 в двоичната система.
=BASE(255;16;4) връща 00FF в шестнадесетичната система.
Преобразува число в знак според текущата кодова таблица. Числото може да бъде двуцифрено или трицифрено цяло число.
CHAR(Число)
Число е число между 1 и 255, представляващо кода на знака.
=CHAR(100) връща знака „d“.
="абв" & CHAR(10) & "где" вмъква знак за нов ред в низа.
Премахва всички непечатаеми знаци от низ.
CLEAN("Текст")
Текст е текстът, от който да бъдат премахнати всички непечатаеми знаци.
=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) връща 16, което показва, че функцията CLEAN е премахнала непечатаемите знаци от Уникод U+0007 ("BEL") и U+0008 ("BS") в началото и края на аргумента низ. CLEAN не премахва интервали.
Връща числов код за първия знак в текстов низ.
CODE("Текст")
Текст е текстът, за който да се намери кодът на първия знак.
=CODE("Hieronymus") връща 72, а =CODE("hieroglyphic") връща 104.
Използваният код не е ASCII, а текущо заредената кодова таблица.
Комбинира няколко текстови низа в един.
CONCATENATE(Низ 1 [; Низ 2 [; … [; Низ 255]]])
Низ 1[; Низ 2][; … ;[Низ 255]] са низове или обръщения към клетки, съдържащи низове.
=CONCATENATE("Добро ";"утро, ";"г-жо ";"Иванова") връща „Добро утро, г-жо Иванова“.
Converts text with characters from a number system to a positive integer in the base radix given. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.
Ако основата е 16, се игнорират водещи знаци „x“, „X“, „0x“ или „0X“ или добавен знак „h“ или „H“. Ако основата 2, се игнорира добавено „b“ или „B“. Останалите знаци, които не принадлежат на бройната система, предизвикват грешка.
DECIMAL("Текст"; Основа)
Текст е текстът, който да бъде преобразуван. За да се различава шестнайсетично число като A1 от обръщение към клетката A1, трябва да оградите числото в кавички, например "A1" или "FACE".
Основа указва основата на бройната система – положително цяло число между 2 и 36.
=DECIMAL("17";10) връща 17.
=DECIMAL("FACE";16) връща 64206.
=DECIMAL("0101";2) връща 5.
Преобразува число към парична сума, закръглена до зададена дробна позиция. В полето Стойност въведете числото, което да се преобразува в парична сума. Ако желаете, можете да въведете броя на дробните позиции в полето ДробниПозиции. Ако не бъде зададена стойност, се подразбират две дробни позиции.
Форматът за валута се задава в системните настройки.
DOLLAR(Стойност [; ДробниПозиции])
Стойност е число, обръщение към клетка с число или формула, която връща число.
ДробниПозиции е незадължителен брой на дробните позиции.
=DOLLAR(255) връща $255.00 за локала „Английски (САЩ)“ и валутата USD (долар); ¥255.00 за локала „Японски“ и валутата JPY (йена); или 255,00 € за локала „Немски (Германия)“ и валутата EUR (евро).
=DOLLAR(367,456;2) връща „367,46 лв.“. Използвайте десетичния разделител, зададен в текущата настройка за локал.
Сравнява два текстови низа и връща TRUE, ако са еднакви. Тази функция е чувствителна към регистъра.
EXACT("Текст1"; "Текст2")
Текст1 е първият текст за сравняване.
Текст2 е вторият текст за сравняване.
=EXACT("microsystems";"Microsystems") връща FALSE.
Връща позицията на един текстов низ в друг. Можете да зададете началната точка на търсенето. Търсеният елемент може да бъде число или произволен знаков низ. Регистърът на буквите има значение.
FIND("ТърсенТекст"; "Текст" [; Позиция])
ТърсенТекст е текстът, който да бъде намерен.
Текст е текстът, който се претърсва.
Позиция (незадължителен) е позицията в текста, от която започва търсенето.
=FIND(76;998877665544) връща 6.
Връща число като текст със зададен брой десетични позиции и – по желание – с разделители на хилядите.
FIXED(Число; [ДробниПозиции = 2 [; БезРазделителНаХилядите = FALSE]])
Число се закръглява до ДробниПозиции разреда (след десетичния разделител) и резултатът се форматира като текст съобразно настройките за конкретния локал.
ДробниПозиции (незадължителен) задава броя на показваните дробни разреди. Ако ДробниПозиции е отрицателен, Число се закръглява до ABS(ДробниПозиции) разреда вляво от десетичната запетая. Ако ДробниПозиции е дроб, дробната му част се премахва, без значение кое е най-близкото цяло число.
БезРазделителНаХилядите (незадължителен) определя дали да се използва разделител на хилядите. Ако е TRUE или ненулев, разделителите на групи се пропускат в низа резултат. Ако параметърът е равен на 0 или липсва, се използва разделителят на хилядите, зададен в текущата настройка за локал.
=FIXED(1234567,89;3) връща „1 234 567,890“ като текстов низ.
=FIXED(123456,789;;TRUE) връща 123456,79 като текстов низ.
=FIXED(12345,6789;-2) връща 12 300 като текстов низ.
=FIXED(12134567,89;-3;1) връща 12135000 като текстов низ.
=FIXED(12345,789;3/4) връща 12 346 като текстов низ.
=FIXED(12345,789;8/5) връща 12 345,8 като текстов низ.
Връща първия знак или знаци на текст.
LEFT("Текст" [; Брой])
Текст е текстът, чието начало да бъде извлечено.
Брой (незадължителен) е броят на знаците от началото на текста. Ако параметърът е пропуснат, се връща един знак.
=LEFT("външен";3) връща „вън“.
Връща първите знаци на текст в двубайтов код (DBCS).
LEFTB("Текст" [; Брой_байтове])
Текст е текстът, чието начало да бъде извлечено.
Брой_байтове (незадължителен) указва броя на знаците, които LEFTB да извлече, като брой байтове. Ако параметърът е пропуснат, се връща един знак.
=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).
=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).
=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).
=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).
=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).
Връща дължината на низ, включително интервалите.
LEN("Текст")
Текст е текстът, чиято дължина да бъде намерена.
=LEN("Добър ден") връща 9.
=LEN(12345,67) връща 8.
За езици с двубайтов знаков набор (DBCS) връща броя байтове, използвани за представяне на знаците в текстов низ.
LENB("Текст")
Текст е текстът, чиято дължина да бъде намерена.
LENB("中") връща 2 (1 DBCS знак, съставен от 2 байта).
LENB("中国") връща 4 (2 DBCS знака, всеки съставен от 2 байта).
LENB("office") връща 6 (6 не-DBCS знака, всеки съставен от 1 байт).
=LENB("Добър ден") връща 9.
=LENB(12345,67) връща 8.
Преобразува всички главни букви в текстов низ в малки букви.
LOWER("Текст")
Текст е текстът, който да бъде преобразуван.
=LOWER("Слънце") връща „слънце“.
Връща част от текстов низ. Параметрите задават началната позиция и броя знаци.
MID("Текст"; Начало; Брой)
Текст е текстът, от който да бъде извлечена част.
Начало е позицията на първия знак в текста, който да бъде извлечен.
Брой е броят на знаците в желаната част на текста.
=MID("office";2;2) връща „ff“.
Връща част от текст в двубайтов код (DBCS). Параметрите задават началната позиция и броя знаци.
MIDB("Текст"; Начало; Брой_байтове)
Текст е текстът, от който да бъде извлечена част.
Начало е позицията на първия знак в текста, който да бъде извлечен.
Брой_байтове указва броя на знаците, които MIDB ще върне от текста, в байтове.
=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).
=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).
=MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).
=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).
=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).
=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).
=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).
=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).
=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).
=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).
=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).
Превръща първите букви на думите в текстов низ в главни букви.
PROPER("Текст")
Текст е текстът, който да бъде преобразуван.
=PROPER("the document foundation") връща „The Document Foundation“.
Заменя част от текстов низ с друг текстов низ. Чрез тази функция може да се заменят както знаци, така и числа (числата автоматично се преобразуват в текст). Резултатът на функцията винаги е текст. Ако възнамерявате да извършвате по-нататъшни изчисления с число, заменено с текст, трябва да го преобразувате обратно в число чрез функцията VALUE.
Текстовете, съдържащи числа, трябва да са заградени с кавички, ако не желаете да бъдат интерпретирани като числа и автоматично преобразувани в текст.
REPLACE("Текст"; Позиция; Дължина; "НовТекст")
Текст е текстът, част от който да бъде заменена.
Позиция е позицията в текста, от която да започне замяната.
Дължина е броят на знаците в Текст, които да бъдат заместени.
НовТекст е текстът, с който да се замени част от Текст.
=REPLACE("1234567";1;1;"444") връща „444234567“. Един знак на позиция 1 е заменен с цялата стойност на НовТекст.
Повтаря знаков низ зададен брой пъти.
REPT("Текст"; Брой)
Текст е текстът, който да бъде повторен.
Брой е броят повторения.
=REPT("Добро утро";2) връща „Добро утроДобро утро“.
Refer to the REPT wiki page for more details about this function.
Връща последния знак или знаци на текст.
RIGHT("Текст" [; Брой])
Текст е текстът, чийто край да бъде извлечен.
Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.
=RIGHT("Слънце";2) връща „це“.
Връща последния знак или знаци на текст с двубайтов знаков набор (DBCS).
RIGHTB("Текст" [; Брой_байтове])
Текст е текстът, чийто край да бъде извлечен.
Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.
RIGHTB("中国"; 1) връща " " (1 байт е само половин DBCS знак и вместо това се връща интервал).
RIGHTB("中国"; 2) връща "国" (2 байта представляват един цял DBCS знак).
RIGHTB("中国"; 3) връща " 国" (3 байта представляват един и половина DBCS знака; затова първият върнат знак е интервал).
RIGHTB("中国"; 4) връща "中国" (4 байта представляват два цели DBCS знака).
RIGHTB("office"; 3) връща "ice" (3 не-DBCS знака, всеки по 1 байт).
Връща позицията на текстов откъс в знаков низ. Ако желаете, можете да зададете началото на търсенето. Търсеният текст може да бъде число или произволна поредица от знаци. Регистърът на буквите е без значение. Ако текстът не бъде намерен, резултатът е грешка 519 (#VALUE).
SEARCH("ТърсенТекст"; "Текст" [; Позиция])
ТърсенТекст е текстът, който се търси.
Текст е текстът, който да бъде претърсен.
Позиция (незадължителен) е позицията в текста, от която да започне търсенето.
=SEARCH(54;998877665544) връща 10.
Замества съществуващ текст в низ с друг текст.
SUBSTITUTE("Текст"; "ТърсенТекст"; "НовТекст" [; Срещане])
Текст е текстът, в който да бъдат заместени откъси.
ТърсенТекст е текстовият откъс, който да бъде заместен (колкото пъти е необходимо).
НовТекст е текстът, с който се заменя съществуващият откъс.
Срещане (незадължителен) указва кое срещане на търсения откъс да бъде заменено. Ако този параметър липсва, се заменят всички копия на откъса.
=SUBSTITUTE("123123123";"3";"абв") връща „12абв12абв12абв“.
=SUBSTITUTE("123123123";"3";"абв";2) връща „12312абв123“.
Тази функция връща подадения текст или празен низ, ако аргументът не е текст.
ISODD(Стойност)
Ако Стойност е текстов низ или посочва такъв, T връща съответния низ. В противен случай се връща празен низ.
=T(12345) връща празен низ.
=T("12345") връща низа „12345“.
Преобразува стойност в текст според зададен формат.
TEXT(Стойност; Формат)
Стойност е стойността (числова или текстова) за преобразуване.
Формат е текстът, който дефинира формата. Използват се десетични разделители и разделители на хилядите според езика, зададен във формата на клетката.
=TEXT(12,34567;"###.##") връща текста „12,35“.
=TEXT(12,34567;"000.00") връща текста „012,35“.
=TEXT("xyz";"=== @ ===") връща текста === xyz ===
Вижте също Кодове на числови формати: кодове на формати по избор, зададени от потребителя.
Премахва интервалите от низ, оставяйки само по един знак за интервал между думите.
TRIM("Текст")
Текст е текстът, от който да бъдат премахнати интервалите.
=TRIM(" Здравей, свят ") връща „Здравей, свят“, без водещи и завършващи интервали и само с един интервал между думите.
Преобразува число в Уникод знак или буква.
UNICHAR(число)
=UNICHAR(169) връща знака за авторски права ©.
Вижте и функцията UNICODE().
Връща числов код за първия знак от текстов низ по стандарта Уникод.
UNICODE("Текст")
=UNICODE("©") връща номера 169 в Уникод на знака за авторски права.
Вижте и функцията UNICHAR().
Преобразува в малки букви низа, зададен в полето Текст.
UPPER("Текст")
Текст е низът с малки букви, които да бъдат преобразувани в главни.
=UPPER("Добро утро") връща „ДОБРО УТРО“.