ScriptForge.Array-teneste

Inneheld ei samling metodar for Ä handsama og transformera matriser av éin dimensjon (vektorar) og matriser med to dimensjonar (matriser). Dette inkluderer Ä setja operasjonar, sortera, importera til og eksportere frÄ tekstfiler.

Matyriser med meir enn to dimensjonar kan ikkje brukast med metodane i denne tenesta. Einaste unnataket er metoden CountDims, som godtar matriser med kor mange dimensjonar som helst.

Matrise-element kan innehalda kva verdi som helst, ogsÄ (under)matriser.

Oppkall av tenester

FÞr du kan bruka tenesta Array, mÄ du henta inn biblioteket ScriptForge ved hjelp av


    GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
  

Lastinga av biblioteket vil laga objektet SF_Array som kan brukast for Ă„ kalla opp metodane i tenesta Array.

Desse kodesnuttane viser dei ulike mÄtane Ä kalla opp metodar pÄ i tenesta Array. Metoden Append er brukt som eksempel:


    Dim arr : arr = Array(1, 2, 3)
    arr = SF_Array.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = SF_Array
    arr = svc.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = CreateScriptService("Array")
    arr = svc.Append(arr, 4)
  
warning

Fordi Python har innebygd stÞtte for liste og tuplar, er dei fleste metodane i Matrise-tenesta berre tilgjengeleg for grunnleggjande skript. Det einaste unntaket er ImportFromCSVFile som vert stÞtta bÄde i Basic og Python.


Liste over metodar i tenesta matrise

Append
AppendColumn
AppendRow
Contains
ConvertToDictionary
Copy
CountDims
Difference
ExportToTextFile
ExtractColumn
ExtractRow

Flatten
ImportFromCSVFile
IndexOf
Insert
InsertSorted
Intersection
Join2D
Prepend
PrependColumn
PrependRow
RangeInit

Reverse
Shuffle
Slice
Sort
SortColumns
SortRows
Transpose
TrimArray
Union
Unique


tip

Det fÞrste argumentet i dei fleste metodane er kva matriseopbjekt som skal vurderast. Den vert alltid sendt med referanse og vert ikkje endra. Metodar som «Append», «Prepend» osv. returnerer eit nytt matrise-objekt etter utfÞringa.


Append

Legg elementa som er oppfÞrte til som argument pÄ slutten av inndatamatrisa.

Syntaks:

svc.Append(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

Parametrar:

matrise_1d: matrisa som finst frÄ fÞr, kan vera tom.

arg0, arg1, ...: Elementer som vert lagt til matrise_1d.

Eksempel:


    Dim a As Variant
    a = SF_Array.Append(Array(1, 2, 3), 4, 5)
        ' (1, 2, 3, 4, 5)
  

AppendColumn

Set inn ein ny kolonne til hĂžgre i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

Syntaks:

svc.AppendColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

Parametrar:

Matrise_2D: Matrisa som finst frÄ fÞr, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den fÞrste kolonnen i den resulterande todimensjonale matrisa.

kolonne: ei eindimensjonal matrise med like mange element som det er rader i matrise_2d.

Eksempel:


    Dim a As Variant, b As variant
    a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((1, 4), (2, 5), (3, 6))
    b = SF_Array.AppendColumn(a, Array(7, 8, 9))
        ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
    c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≀ i ≀ 2} : b(0, i) ≡ i
  

AppendRow

Legg til ei ny rad nedst i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege matrisa.

Syntaks:

svc.AppendRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*])

Parametrar:

Matrise_2d: Matrisa som finst frÄ fÞr. Kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den fÞrste rada i den nye todimensjonale matrisa.

Rad: Ei eindimensional matrise med like mange element som det er rader i matrise_2d.

Eksempel:


    Dim a As Variant, b As variant
    a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
        '  ((1, 2, 3), (4, 5, 6))
    b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≀ i ≀ 2} : b(i, 0) ≡ i
  

Contains

SjÄ etter om ei eindimensjonal matrise inneheld eit bestemt tal, ein bestemt tekst eller dato. Tekstsamanlikningar kan skilja mellom store og smÄ bokstavar.
Sorterte inndatamatriser mÄ fyllast ut homogent, det vil seia at alle elementa mÄ vera skalarar av same type (Tomme- og Null-element kan ikkje brukast).
Det er urÄd Ä vita pÄ fÞrehand kva resultatet av metoden vert nÄr matrisa er sagt Ä vera sortert utan at ho er det.
Det vert utfÞrt eit binÊrsÞk nÄr matrisa er sortert, elles vert ho skanna frÄ Þvst til nedst og Tomme element og Nullelement vert ignorerte.

Syntaks:

svc.Contains(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ""): bool

Parametrar:

matrise_1d: Matrisa som skal skannast.

ÅFinna: Eit tal, ein dato eller ein streng som skal finnast.

skilje mellom store og smÄ bokstavar: Berre for strengsamanlikningar (Standard = Usann).

sorteringsrekkjefĂžlgje: Det kan anten vera "ASC", "DESC" eller "" (ikkje sortert). Standardverdien er "".

Eksempel:


    Dim a As Variant
    a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
    SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
  

ConvertToDictionary

Lagrar innhaldet av ei matrise med to kolonnar i eit ScriptForge.Dictionary-objekt.
NÞkkelen vert henta ut frÄ den fÞrste kolonnen, elementet frÄ den andre.

Syntaks:

svc.ConvertToDictionary(array_2d: any[0..*, 0..1]): obj

Parametrar:

matrise_2d: Data som skal konverterast til eit ScriptForge.Dictionary-objekt.

Eksempel:


    Dim a As Variant, b As Variant
    a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
    b = SF_Array.ConvertToDictionary(a)
    MsgBox b.Item("c") ' 3
  

Copy

Lagar ein kopi av ei 1D- eller 2D-matrise.

Syntaks:

svc.Copy(array_nd: any[0..*]): any[0..*]

svc.Copy(array_nd: any[0..*, 0..*]): any[0..*, 0..*]

Parametrar:

matrise_nd: 1D- eller 2D-matrisa som skal kopierast.

Eksempel:

Ei enkel tilordning av eit matrise-objekt vil kopiera referansen i staden for Ä laga ein kopi av innhaldet i objektet. SjÄ eksempelet nedanfor:


    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' Tilordninga nedanfor er laga ved referanse
    b = a
    ' Difor vil endring av verdiar i «b» ogsÄ endra «a»
    b(0) = 10
    MsgBox a(0) ' 10
  

By using the Copy method, a copy of the whole Array object is made. In the example below, a and b are different objects and changing values in b will not affect values in a.


    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' Creates a copy of "a" using the "Copy" method
    b = SF_Array.Copy(a)
    b(0) = 10
    MsgBox a(0) ' 1
  

CountDims

Count the number of dimensions of an array. The result can be greater than two.
If the argument is not an array, returns -1
If the array is not initialized, returns 0.

Syntaks:

svc.CountDims(array_nd: any): int

Parametrar:

array_nd: The array to examine.

Eksempel:


    Dim a(1 To 10, -3 To 12, 5)
    MsgBox SF_Array.CountDims(a) ' 3
  

Difference

Bygg eit sett som ei null-basert matrise, ved Ä bruka differensoperatoren pÄ dei to inndatamatrisene. Resulterande element kjem frÄ den fÞrste matrisa og ikkje frÄ den andre.
Den resulterande matrisa vert sortert i stigande rekkjefĂžlgje.
Begge inndatamatrisene mÄ fyllast homogent, elementa mÄ vera skalarar av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og smÄ bokstavar eller ikkje.

Syntaks:

svc.Difference(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametrar:

array1_1d: A 1-dimensional reference array, whose items are examined for removal.

array2_1d: A 1-dimensional array, whose items are subtracted from the first input array.

casesensitive: This argument is only applicable if the arrays are populated with strings (Default = False).

Eksempel:


    Dim a As Variant
    a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B")
  

ExportToTextFile

Skriv alle matriseelementa i nummerrekkjefÞlgje til ei tekstfil. Viss fila finst frÄ fÞr, vert ho overskrive utan varsel.

Syntaks:

svc.ExportToTextFile(array_1d: any[0..*], filename: str, [encoding: str]): bool

Parametrar:

array_1d: The array to export. It must contain only strings.

filename: The name of the text file where the data will be written to. The name must be expressed according to the current FileNaming property of the SF_FileSystem service.

encoding: The character set that should be used. Use one of the names listed in IANA character sets. Note that LibreOffice may not implement all existing character sets (Default is "UTF-8").

Eksempel:


    SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
  

ExtractColumn

Trekk ut ein bestemt kolonne frÄ ei todimensjonal matrise som ei ny matrise.
Dei nedre LBound og Ăžvre UBound grensene er dei same som dei brukte i fĂžrste dimensjon av innmatrisa.

Syntaks:

svc.ExtractColumn(array_2d: any[0..*, 0..*], columnindex: int): any[0..*, 0..*]

Parametrar:

array_2d: The array from which to extract.

columnindex: The column number to extract - must be in the interval [LBound, UBound].

Eksempel:


    'Lagar ei 3 × 3 matrise: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, col as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    'Trekk ut den tredje kolonnen: |3, 6, 9|
    col = SF_Array.ExtractColumn(mat, 2)
  

ExtractRow

Trekk ut ei bestemt rad som ei ny matrise frÄ ei to-dimensjonal matrise.
Nedre (LBound) og Ăžvre (UBound) grense er lik grensene i den andre dimensjonen i inndatamatrisa.

Syntaks:

svc.ExtractRow(array_2d: any[0..*, 0..*], rowindex: int): any[0..*, 0..*]

Parametrar:

array_2d: The array from which to extract.

rowindex: The row number to extract - must be in the interval [LBound, UBound].

Eksempel:


    ' Lagar ei 3 × 3 matrise: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, row as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    ' Trekk ut den fĂžrste rada: |1, 2, 3|
    row = SF_Array.ExtractRow(mat, 0)
  

Flatten

Stablar alle enkeltelementa i ei matrise og alle elementa i delmatrisene i éi ny matrise utan delmatriser. Tomme delmatriser vert ignorerte og delmatriser med stÞrre dimensjonar enn éin vert ikkje slegne saman.

Syntaks:

svc.Flatten(array_1d: any[0..*]): any[0..*]

Parametrar:

array_1d: The pre-existing array, may be empty.

Eksempel:


    Dim a As Variant
    a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
        ' (1, 2, 3, 4, 5)
  
tip

Du kan bruka metoden Flatten saman med andre metodar som for eksempel Append eller Prepend for Ä kopla saman eit sett med 1D-matriser til éi enkelt 1D-matrise.


Eksempel:

Neste eksempel viser korleis metodane Flatten og Append kan kombinerast for Ă„ setja saman tre matriser.


    ' Lager tre matriser til dette eksempelet
    Dim a as Variant, b as Variant, c as Variant
    a = Array(1, 2, 3)
    b = Array(4, 5)
    c = Array(6, 7, 8, 9)
    ' SlÄr saman dei tre matrisene til éi 1D-matrise
    Dim arr as Variant
    arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
    '(1, 2, 3, 4, 5, 6, 7, 8, 9)
  

ImportFromCSVFile

Importer dataa frÄ ei kommadelt fil (CSV). Kommaet kan bytast ut med kva teikn som helst.

Det aktuelle CSV-formatet er forklart i IETF Common Format and MIME Type for CSV Files.

Kvar linje i fila inneheld ein fullstendig post (linjedeling er ikkje tillate).
Sekvensar som \n, \t, 
 vert uendra. Bruk SF_String, Unescape()-metoden for Ă„ administrera dei.

Metoden returnerer ei matrise med to dimensjonar der radene svarar til éin enkelt post i fila, og der kolonnane svarar til eitt felt i posten. Det vert ikkje kontrollert om felttypane er samanhengande pÄ tvers av kolonnar. Det vert gjort ei beste gissing for Ä identifisera numeriske typar og datotypar.

Viss ei linje inneheld fÊrre eller fleire felt enn den fÞrste linja i fila, vert det sett eit unntak. Tomme linjer vert ganske enkelt ignorerte. Viss fila er stÞrre enn grensa for talet pÄ element (sjÄ i koden), vert det vist ei Ätvaring og matrisa vert avkorta.

Syntaks:

svc.ImportFromCSVFile(filename: str, delimiter: str = ',', dateformat: str = ''): any[0..*]

Parametrar:

filename: The name of the text file containing the data. The name must be expressed according to the current FileNaming property of the SF_FileSystem service.

delimiter: A single character, usually, a comma, a semicolon or a TAB character (Default = ",").

dateformat: A special mechanism handles dates when dateformat is either "YYYY-MM-DD", "DD-MM-YYYY" or "MM-DD-YYYY". The dash (-) may be replaced by a dot (.), a slash (/) or a space. Other date formats will be ignored. Dates defaulting to an empty string "" are considered as normal text.

Eksempel:

Consider the CSV file "myFile.csv" with the following contents:

Name,DateOfBirth,Address,City

Anna,2002/03/31,"Rue de l'église, 21",Toulouse

Fred,1998/05/04,"Rue Albert Einstein, 113A",Carcassonne

The examples below in Basic and Python read the contents of the CSV file into an Array object.

I Basic

    Dim arr As Variant
    arr = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY/MM/DD")
    MsgBox arr(0, 3) ' City
    MsgBox arr(1, 2) ' Rue de l'église, 21
    MsgBox arr(1, 3) ' Toulouse
  
I Python

    from scriptforge import CreateScriptService
    svc = CreateScriptService("Array")
    bas = CreateScriptService("Basic")
    arr = svc.ImportFromCSVFile(r"C:\Temp\myFile.csv", dateformat = "YYYY/MM/DD")
    bas.MsgBox(arr[0][3]) # City
    bas.MsgBox(arr[1][2]) # Rue de l'église, 21
    bas.MsgBox(arr[1][3]) # Toulouse
  

IndexOf

SjÄ etter eit tal, ein streng eller ein dato i ei eindimensjonal matrise. Tekstsamanlikning kan skilja mellom store og smÄ bokstavar, eller ikkje.
Viss matrisa er sortert, mÄ ho vera utfylt homogent, altsÄ at alle elementa mÄ vera skalarar av same type (Empty og Null kan ikkje brukast).
NÄr matrisa er sett til Ä vera sortert men ikkje er det, er det urÄd Ä vita resultatet pÄ fÞrehand.
Det vert brukt binÊrt sÞk pÄ sorterte matriser. Elles vert matriser ganske enkelt skanna frÄ topp til botn. Elementa Empty og Null vert ikkje tekne med.

Metoden returnerer LBound(input array) - 1 viss sĂžket ikkje var vellukka.

Syntaks:

svc.IndexOf(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ''): int

Parametrar:

array_1d: The array to scan.

tofind: A number, a date or a string to find.

casesensitive: Only for string comparisons (Default = False).

sorteringsrekkjefĂžlgje: Det kan anten vera "ASC", "DESC" eller "" (ikkje sortert). Standardverdien er "".

Eksempel:


    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
  

Insert

Set inn elementa som er oppfĂžrt som argument framfĂžre ein gjeven indeks for inndatamatrisa.
Argument vert sette inn blindt. Kvart av dei kan anten vera ein skalar av kva type som helst eller ei undermatrise.

Syntaks:

svc.Insert(array_1d: any[0..*], before: int, arg0: any, [arg1: any] ...): any[0..*]

Parametrar:

array_1d: The pre-existing array, may be empty.

before: The index before which to insert; must be in the interval [LBound, UBound + 1].

arg0, arg1, 
: Element som vert sette inn i matrise_1d.

Eksempel:


    Dim a As Variant
    a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
        ' (1, 2, "a", "b", 3)
  

InsertSorted

Set inn eit nytt element pÄ plassen sin i ei sortert matrise.
Matrisa mÄ fyllast homogent, altsÄ at alle elementa mÄ vera skalarer av same type.
Elementa Empty og Null er ikkje tillatne.

Syntaks:

svc.InsertSorted(array_1d: any[0..*], item: any, sortorder: str = 'ASC', casesensitive: bool = False): any[0..*]

Parametrar:

matrise_1d: Matrisa som verdien skal setjast inn i.

Element: Skalarverdien som skal setjast inn. Av same type som matriseelementa som finst frÄ fÞr.

sorteringsrekkjefĂžlgje: Det kan anten vera "ASC" (standard) eller "DESC".

skilje mellom store og smÄ bokstavar: Berre for strengsamanlikningar (Standard = Usann).

Eksempel:


    Dim a As Variant
    a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

Intersection

Bygg eit sett som ei null-basert matrise ved Ä bruka unionmengde-operatoren pÄ dei to inndatamatrisene. Resulterande element kjem frÄ begge matrisene.
Den resulterande matrisa vert sortert i stigande rekkjefĂžlgje.
Begge inndatamatrisene mÄ fyllast homogent, elementa mÄ vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og smÄ bokstavar eller ikkje.

Syntaks:

svc.Intersection(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametrar:

array1_1d: Den fĂžrste inndatamatrisa.

array2_1d: Den andre inndatamatrisa.

skil mellom store og smÄ bokstavar: Gjeld for matriser fylt med tekstelement (standard = Usann).

Eksempel:


    Dim a As Variant
    a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("C", "b")
  

Join2D

FĂžyer saman ei todimensjonal matrise med to skiljeteikn, eitt for kolonnane, eitt for radene.

Syntaks:

svc.Join2D(array_2d: any [0..*, 0..*], [columndelimiter: str], [rowdelimiter: str], [quote: str]): str

Parametrar:

array_2d: Kvart element mÄ vera anten tekst, eit tall, ein dato eller ein boolsk verdi.
Datoar vert omforma til formatet ÅÅÅÅ-MM-DD tt:mm:ss.
Ugyldige element vert byt ut med ein streng med null lengd.

Kolonneskiljeteikn: Skilje mellom kolonnar (standard = Tab/Chr(9)).

Radskiljeteikn: Skil mellom radene (standard = LineFeed/Chr(10))

Hermeteikn: viss Sann vert strengen verna med doble hermeteikn ("). Standarden er Usann.

Eksempel:


    ' arr = | 1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5           |
    '       | 6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10 |
    Dim arr as Variant : arr = Array()
    arr = SF_Array.AppendRow(arr, Array(1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5))
    arr = SF_Array.AppendRow(arr, Array(6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10))
    Dim arrText as String
    arrText = SF_Array.Join2D(arr, ",", "/", False)
    ' 1,2,A,,51,2,A,,5/6,7,this is a string,9,106,7,this is a string,9,10
  

Prepend

Legg dei utlista elementa til som argument i byrjinga av inndatamatrisa.

Syntaks:

svc.Prepend(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

Parametrar:

matrise_1d: matrisa som finst frÄ fÞr, kan vera tom.

arg0, arg1 
: ei liste over element som skal setjast inn fþrst i Matrise_1d.

Eksempel:


    Dim a As Variant
    a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
        ' (4, 5, 1, 2, 3)
  

PrependColumn

Legg til ein ny kolonne fÞrst pÄ venstre side i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

Syntaks:

svc.PrependColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

Parametrar:

Matrise_2d: matrisa som finst frÄ fÞr, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den fÞrste rada i den nye todimensjonale matrisa.

kolonne: ei eindimensional matrise med like mange element som det er rader i array_2d.

Eksempel:


    Dim a As Variant, b As variant
    a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 1), (5, 2), (6, 3))
    b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≀ i ≀ 2} : b(0, i) ≡ i
  

PrependRow

Legg til ei ny rad fĂžrst i ei todimensjonal matrise. Den nye matrisa har dei same nedre grensene som den opphavlege todimensjonale matrisa.

Syntaks:

svc.PrependRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*]

Parametrar:

matrise_2d: matrisa som finst frÄ fÞr, kan vera tom. Viss denne matrisa har berre éin dimensjon, vert denne rekna som den siste rada i den nye todimensjonale matrisa.

Rad: ei eindimensional matrise med like mange element som det er rader i matrise_2d.

Eksempel:


    Dim a As Variant, b As variant
    a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 5, 6), (1, 2, 3))
    b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≀ i ≀ 2} : b(i, 0) ≡ i
  

RangeInit

Initialiser ei ny null-basert matrise med numeriske verdiar.

Syntaks:

svc.RangeInit(from: num, upto: num, [bystep: num]): num[0..*]

Parametrar:

frÄ: verdien av det fÞrste elementet.

Opptil: Det siste elementet mÄ ikkje overstige Opptil.

Trinnvis: Differansen mellom to etterfĂžlgjande element (standard = 1).

Eksempel:


    Dim a As Variant
    a = SF_Array.RangeInit(10, 1, -1)
        ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
  

Reverse

Returner den omvendte eindimensjonelle inndata-matrisa.

Syntaks:

svc.Reverse(array_1d: any[0..*]): any[0..*]

Parametrar:

matrise_1d: matrisa som skal reverserast.

Eksempel:


    Dim a As Variant
    a = SF_Array.Reverse(Array("a", 2, 3, 4))
        ' (4, 3, 2, "a")
  

Shuffle

Returnerer ein tilfeldig permutasjon av ei eindimensjonal matrise.

Syntaks:

svc.Shuffle(array_1d: any[0..*]): any[0..*]

Parametrar:

matrise_1d: matrisa som skal blandast.

Eksempel:


    Dim a As Variant
    a = SF_Array.Shuffle(Array(1, 2, 3, 4))
        ' Matrisa "a" er nÄ i tilfeldig rekkefÞlgje, f.eks. (2, 3, 1, 4)
  

Slice

Returner eit delsett av ei eindimensjonal matrise.

Syntaks:

svc.Slice(array_1d: any[0..*], from: int, [upto: int]): any[0..*]

Parametrar:

matrise_1d: Matrisa som skal delast.

frÄ: Den lÄgaste indeksen i matrise_1d av delmatrisa som skal trekkjast ut (frÄ vert teken med.

opptil: Det Þvste indeks i matrise_1d av den delmatrisa som det skal trekkjast ut frÄ (opptil medrekna). Standard = Þvre grense for matrise_1d. Viss opptil < frÄ, vert det returnert ei tom matrise.

Eksempel:


    Dim a As Variant
    a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
  

Sort

Sorter ei eindimensjonal matrise i stigande eller falande rekkjefÞlgje. Tekstsamanlikningar kan skilja mellom store og smÄ bokstavar eller ikkje.
Matrisa skal vera fylt homogent, altsÄ at elementa mÄ vera av same type skalarar.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva skalarverdi som helst.

Syntaks:

svc.Sort(array_1d: any[0..*], sortorder: str, casesensitive: bool = False): any[0..*]

Parametrar:

matrise_1d: Matrisa som skal sorterast.

sorteringsrekkjefĂžlgje: Det kan anten vera "ASC" (standard) eller "DESC".

skilje mellom store og smÄ bokstavar: Berre for strengsamanlikningar (Standard = Usann).

Eksempel:


    Dim a As Variant
    a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

SortColumns

Returner ein permutasjon av kolonnar i ei todimensional matrise, sortert etter verdiane i ei gjeven rad.
Rada mÄ vera fylt homogent, altsÄ at alle elementa mÄ vera skalarer av same type.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva annan skalar verdi som helst.

Syntaks:

svc.SortColumns(array_2d: any[0..*, 0..*], rowindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

Parametrar:

matrise_2d: Den todimensjonale matrisa som skal sorterast.

radindeks: Indeksen til rada som skal brukast som referanse for Ă„ sortera kolonnane.

sorteringsrekkjefĂžlgje: Det kan anten vera "ASC" (standard) eller "DESC".

skilje mellom store og smÄ bokstavar: Berre for strengsamanlikningar (Standard = Usann).

Eksempel:


    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortColumns(arr, 2, "ASC")
    ' arr = | 7, 5, 3 |
    '       | 9, 1, 5 |
    '       | 1, 6, 8 |
  

SortRows

Returner ein permutasjon av kolonnar i ei todimensional matrise, sortert etter verdiane i ei gjeven rad.
Rada mÄ vera fylt homogent, altsÄ at alle elementa mÄ vera skalarer av same type.
Elementa Empty og Null er tillatne. Til vanleg er Empty < Null < kva annan skalar verdi som helst.

Syntaks:

svc.SortRows(array_2d: any[0..*, 0..*], columnindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

Parametrar:

matrise_1d: Matrisa som skal sorterast.

kolonneindeks: Indeksen til kolonnen som skal brukast som referanse for Ă„ sortera radene.

sorteringsrekkjefĂžlgje: Det kan anten vera "ASC" (standard) eller "DESC".

skilje mellom store og smÄ bokstavar: Berre for strengsamanlikningar (Standard = Usann).

Eksempel:


    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortRows(arr, 0, "ASC")
    ' arr = | 1, 9, 5 |
    '       | 5, 7, 3 |
    '       | 6, 1, 8 |
  

Transpose

Byter om rader og kolonnar i ei todimensjonal matrise.

Syntaks:

svc.Transpose(array_2d: any[0..*, 0..*]): any[0..*, 0..*]

Parametrar:

matrise_2d: Den todimensjonale matrisa som skal transponerast.

Eksempel:


    ' arr1 = | 1, 2 |
    '        | 3, 4 |
    '        | 5, 6 |
    arr1 = Array(1, 2)
    arr1 = SF_Array.AppendRow(arr1, Array(3, 4))
    arr1 = SF_Array.AppendRow(arr1, Array(5, 6))
    arr2 = SF_Array.Transpose(arr1)
    ' arr2 = | 1, 3, 5 |
    '        | 2, 4, 6 |
    MsgBox arr2(0, 2) ' 5
  

TrimArray

Fjern alle Null, Empty og nul-lengde-oppfÞringar frÄ ei eindimensjonal matrise.
Strengelementa kan trimmast med funksjonen LibreOffice Basic Trim() .

Syntaks:

svc.TrimArray(array_1d: any[0..*]): any[0..*]

Parametrar:

matrise_1d: Matrisa som skal trimmast.

Eksempel:


    Dim a As Variant
    a = SF_Array.TrimArray(Array("A", "B", Null, " D "))
        ' ("A", "B", "D")
  

Union

Bygg eit sett som ei null-basert matrise ved Ä bruka unionmengde-operatoren pÄ dei to inndatamatrisene. Resulterande element kjem frÄ ei av begge matrisene.
Den resulterande matrisa vert sortert i stigande rekkjefĂžlgje.
Begge inndatamatrisene mÄ fyllast homogent, elementa mÄ vera skalarer av same type. Elementa Empty og Null kan ikkje brukast.
Tekstsamanlikning kan skilja mellom store og smÄ bokstavar eller ikkje.

Syntaks:

svc.Union(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametrar:

matrise1_1d: Den fĂžrste inndatamatrisa.

matrise2_1d: Den andre inndatamatrisa.

skill mellom store og smÄ bokstavar: Gjeld berre viss matrisene er fylte med strenger (standard = Usann).

Eksempel:


    Dim a As Variant
    a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B", "C", "Z", "b")
  

Unique

Bygg eit sett av unike verdiar avleidde frÄ inndata-matrisa.
Inndata-matrisa mÄ vera fylt homogent, altsÄ at alle elementa mÄ vera skalarer av den same typen. Elementa Empty og Null er ikkje tillatne.
Tekstsamanlikningar kan skilja mellom store og smÄ bokstavar eller ikkje.

Syntaks:

svc.Unique(array_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametrar:

matrise_1d : Inndata-matrisa.

casesensitive: Applicable only if the array is populated with strings (Default = False).

Eksempel:


    Dim a As Variant
    a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
        '  ("A", "B", "C", "b")
  
warning

Alle ScriptForge Basic-rutinane og -identifikatorane som vert innleidde med understrek «_» er reserverte for internt bruk. Dei er ikkje meint brukte i Basic-makroar.